'==============================================================================
'Bigpond Broadband usage monitoring script
'by Darryn Jones
'http://www.darryn.net/
'
'22 June 2004
'
'improved 23 July 2004 by TristanK http://www.tristank.com/
'(added winhttp, removing requirement for lynx)
'
'if you improve this script, please send me a copy
'==============================================================================

Dim winhttp
Dim Username
Dim Password
Dim upload
Dim download
Dim total
Dim site
dim proxy
dim proxyuser
dim proxypassword


site = "https://account.bigpond.com/broadband/usage/toolbar/toolbar.do"
set winhttp = CreateObject("WinHttp.WinHttpRequest.5")

'****Edit here****
Username = "Username" 'put in yuor real bigpond username 
Password = "Password" 'put in yuor real bigpond password
proxy = "proxyserver:8080" 'put in yuor proxy address and port
proxyuser = "proxyusername"  ' put in yuor proxy username
proxypassword = "proxypassword" 'put in yuor proxy passsword
'****End Edit****


winhttp.Open "GET", site, False
winhttp.SetCredentials Username, Password, 0   ' 0 = for server, not for proxy, 1 = proxy credentials. Use both if necessary.
' NB untested bit for proxy server usage (line 1) and authentication (line 2).
' winhttp.SetProxy 2, proxy
' winhttp.SetCredentials proxyuser, proxypassword, 1
winhttp.Send

set xmlDoc = CreateObject("Microsoft.XMLDOM")
xmlDoc.loadXML(winhttp.ResponseText)


Set objLst = xmlDoc.getElementsByTagName("*")

 For i = 0 to (objLst.length - 1)

    If objLst.item(i).nodeName = "upload" Then
      upload = objLst.item(i).text
      
    End If

    If objLst.item(i).nodeName = "download" Then
      download = objLst.item(i).text
      Exit For
    End If
    
 Next

total = CInt(upload) + CInt(download)

wscript.echo total
wscript.echo upload

wscript.echo Date() & " " & Time()

wscript.echo "Total Usage"
wscript.echo "Upload Usage"


'"yuor" is not a typo. It is part of BPC lore.